PowerBI

資料設定

設定API

Get data -> Blank Query

開啟一個空白的Query來編輯

alt text

點擊Advanced Editor

alt text

輸入以下範例Query

let
    // API URL
    apiUrl = "https://www.weincloud.net/dashboard/api/v2/open_api/history",

    // 取得UTC時間
    endDate = DateTimeZone.UtcNow(),

    // 前3小時
    startDate = endDate - #duration(0, 3, 0, 0),

    // 轉換為ISO8601格式
    formattedStartDate = DateTimeZone.ToText(startDate, "yyyy-MM-ddTHH:mm:ssZ"),
    formattedEndDate = DateTimeZone.ToText(endDate, "yyyy-MM-ddTHH:mm:ssZ"),
    
    // JSON請求體
    requestBody = Json.FromValue([
        start = formattedStartDate,
        end = formattedEndDate,
        tags = {
            [
                hw_key = "請在此輸入您的HWKEY !!!",
                name = "請在此輸入您的Tag名稱 !!!"
            ]
        }
    ]),

    // HTTP請求標頭
    requestHeaders = [
        #"Content-Type" = "application/json",
        #"X-API-KEY" = "請在此輸入您的API KEY !!!"
    ],

    // POST請求
    Source = Web.Contents(
        apiUrl,
        [
            Headers = requestHeaders,
            Content = requestBody,
            Timeout = #duration(0, 0, 5, 0)
        ]
    ),

    // JSON回應
    raw = Json.Document(Source),
    dList = raw[d],

    // 展開陣列
    dTable = Table.FromList(dList, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
    dExpanded = Table.ExpandRecordColumn(dTable, "Column1", {"hw_key", "name", "values"}),
    valuesExpanded = Table.ExpandListColumn(dExpanded, "values"),
    valuesFlattened = Table.ExpandRecordColumn(valuesExpanded, "values", {"value", "hmi_time"}),

    // 將value轉換為數字
    #"Changed Type" = Table.TransformColumnTypes(valuesFlattened, {{"value", type number}}),

    // 將hmi_time轉換為日期時間類型
    withDateTime = Table.AddColumn(
        #"Changed Type",
        "hmi_datetime",
        each DateTime.From(#datetime(1970, 1, 1, 0, 0, 0) + #duration(0, 0, 0, [hmi_time] / 1000)),
        type datetime
    )
in
    withDateTime